Side-by-side installation of snapmaker Orca

Software Snapmaker Orca
1

Is it possible to have two or more installments of Snorca on the same computer?

Since it creates its folders with a fixed name in the user (sub)folders, you might have a clash if you are testing a beta version along your production release. I thought that the portable version would keep its folders to its own, but this doesn’t seem to be the case.

2

I am doing that from time to time. I am running Snorca on a Mac Mini M4.

In that case I don’t drag the app file into the regular apps folder, but into a different one.

regards

Manfred

3

I found the proper way:

(Snapmaker) Orca has a lot of command line functions and startup parameters.

Amongst them is the parameter --datadir, followed by de name of the folder.

I used the portable version and copied into a folder.

I created a shortcut on my desktop and added the parameter --datadir D:\MyFolder.

Then I started the exe by its shortcut for the first time

The installed setting files now reside in the given folder and not in the usual one.

4

This one has it’s own directories:

5

You can do that with snapmaker orcaslicer.

Download the .zip portable version of a build, unzip into its own folder, and it can be anywhere you want.

In that folder, create a new “Run Snapmaker Orca.txt” file, and paste the following content in. File name can be anything you want.

@echo off
REM Standalone portable launcher for Snapmaker Orca. No PowerShell, no dependency on any
REM other file - drop this next to snapmaker-orca.exe and double-click it.
REM
REM Config is written to .\Snapmaker_Orca-data beside the exe, so the folder is entirely
REM self-contained: nothing goes to %APPDATA%, and deleting the folder removes every trace.
REM
REM NOTE the launcher is snapmaker-orca.exe - lowercase, hyphenated. Snapmaker_Orca is the
REM .dll and the install-directory name only.
setlocal
set "EXE=%~dp0snapmaker-orca.exe"
set "DATA=%~dp0Snapmaker_Orca-data"

if not exist "%EXE%" (
    echo.
    echo   snapmaker-orca.exe was not found next to this script.
    echo   Expected: "%EXE%"
    echo.
    echo   Keep this file in the same folder as snapmaker-orca.exe.
    echo.
    pause
    exit /b 1
)

if not exist "%DATA%" mkdir "%DATA%"

start "" "%EXE%" --datadir "%DATA%" %*
endlocal

save, and change Run “Snapmaker Orca.txt” to “Run Snapmaker Orca.cmd”.

Now when you double click this “Run Snapmaker Orca.cmd”, it will launch the snapmaker-orca.exe in the same folder, and put all the settings in “Snapmaker_Orca-data” folder in the same location. Do not run snapmaker-orca.exe any more, otherwise it will use the

%appdata%\Snapmaker_Orca

path, and MAY cause conflicts.

You can also copy this .cmd file to other builds of snapmaker orca.

6

Thank you for sharing my build.